loose/flake.nix at master · seqizz/loose · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "A simple tool to apply XrandR configurations";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs = { self, nixpkgs, flake-utils }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = nixpkgs.legacyPackages.${system};
        python = pkgs.python3;
        pyproject = builtins.fromTOML (builtins.readFile ./pyproject.toml);
        pyedid = python.pkgs.callPackage ./nix/pyedid.nix {};
      in {
        packages.default = python.pkgs.buildPythonApplication {
          pname = "loose";
          version = pyproject.project.version;
          pyproject = true;

          src = ./.;

          nativeBuildInputs = with python.pkgs; [
            hatchling
            pkgs.installShellFiles
          ];

          buildInputs = with python.pkgs; [
            shtab # For command line completion
          ];

          propagatedBuildInputs = with python.pkgs; [
            filelock
            jc
            pkgs.xrandr
            pyedid
            pyyaml
            typing-extensions
            xdg-base-dirs
            yamale
          ];

          # Sadly shtab doesn't have fish completion yet
          postInstall = ''
            export HOME=$TMPDIR
            $out/bin/loose -s bash > $HOME/loose.bash
            $out/bin/loose -s zsh > $HOME/loose.zsh
              installShellCompletion --cmd loose \
                --bash $HOME/loose.bash \
                --zsh $HOME/loose.zsh
          '';

          meta = with pkgs.lib; {
            description = "Another xrandr wrapper for multi-monitor setups";
            homepage = "https://git.gurkan.in/gurkan/loose";
            license = licenses.gpl3;
            maintainers = ["seqizz"];
            platforms = platforms.linux;
          };
        };

        devShells.default = pkgs.mkShell {
          packages = [
            python
            pkgs.uv
            pkgs.xrandr
          ];
        };
      }
    );
}