dotconfig/flake.nix at main · niklasmohrin/dotconfig · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
{
  description = "NixOS and Home Manager configuration of niklas";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs/nixos-26.05";
    nixpkgs-unstable.url = "github:nixos/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs-unstable";
    };
    nixos-hardware = {
        url = "github:NixOS/nixos-hardware/master";
        inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = inputs@{ nixpkgs, nixpkgs-unstable, home-manager, ... }:
    let
      system = "x86_64-linux";
      pkgs = import nixpkgs { inherit system; };
      pkgs-unstable = import nixpkgs-unstable { inherit system; };
      inherit (pkgs) lib;
      username = "niklas";
    in
    rec
    {
      inherit pkgs pkgs-unstable;

      nixosModules = lib.mapAttrs'
        (filename: _: { name = lib.strings.removeSuffix ".nix" filename; value = import ./nixosModules/${filename}; })
        (builtins.readDir ./nixosModules);

      nixosConfigurations = {
        niks-xps = nixpkgs.lib.nixosSystem {
          inherit system;
          modules = [ ./machines/niks-xps ];
          specialArgs = { inherit inputs username nixosModules pkgs-unstable; };
        };
        niks-fw = nixpkgs.lib.nixosSystem {
          inherit system;
          modules = [ ./machines/niks-fw ];
          specialArgs = { inherit inputs username nixosModules pkgs-unstable; };
        };
      };

      homeConfigurations = {
        "niklas@niks-fw" = home-manager.lib.homeManagerConfiguration {
          pkgs = pkgs-unstable;
          modules = [ ./home.nix ./homeModules/niri.nix ];
        };
        "niklas@BETAL207479" = home-manager.lib.homeManagerConfiguration {
          pkgs = pkgs-unstable;
          modules = [ ./home.nix ./homeModules/ubuntu.nix ];
        };
      };

      devShells.${system}.default = pkgs.mkShell {
        packages = [
          (pkgs.python3.withPackages (ps: with ps; [
            python-lsp-server
            pylsp-mypy
            pylsp-rope
            python-lsp-black
            isort
            python-lsp-ruff
            qtile
          ]))
        ];
      };
    };
}