installer/flake.nix at main · finix-community/installer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
{
  description = "finix installer ISO";

  # same revisions as calamares-finix-extensions/src/modules/nixos/main.py,
  # so the packages prebuilt into the ISO are the ones the installed system uses
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/e2587caef70cea85dd97d7daab492899902dbf5d";
    finix.url = "github:finix-community/finix/8a9b75a16b6f399e12d031dcd714a938af40c9b5";
    noctalia-src = {
      url = "github:noctalia-dev/noctalia-shell/3d7b9869950592ff7cf3704f6a53afb169d850db";
      flake = false;
    };
    nvwm-src = {
      url = "github:Vifuddyxg/nvwm/58bfe34f14d532b6fdcac3149133cccd2e3bf653";
      flake = false;
    };
    vxwm-src = {
      url = "git+https://codeberg.org/wh1tepearl/vxwm?rev=8b9f04c415a96c92fc36b7639cd1877903f3f0eb";
      flake = false;
    };
    gluewc-src = {
      url = "github:vladbiber/gluewc/d824fe84c3adf309d5ede657ea3c1a3863bceb3a";
      flake = false;
    };
    glueqs-src = {
      url = "github:vladbiber/glueqs/9962580548892ccf7f3e9a2750c77925c6babe09";
      flake = false;
    };
    scenefx-src = {
      url = "github:wlrfx/scenefx/37ccd723bef49e6891156ffafce8f549f01446cc";
      flake = false;
    };
    newm-flake.url = "github:jbuchermn/newm/d120fcc390eba70593aecfafbafefe8647fd5c92";
  };

  outputs = inputs @ { self, nixpkgs, finix, noctalia-src, newm-flake, ... }: let
    lib = nixpkgs.lib;

    pkgsTarget = import nixpkgs {
      system = "x86_64-linux";
      config.allowUnfree = true;
    };

    # the two systems the installer can produce with every desktop selected:
    # eudev + elogind (plasma) and mdevd + seatd (everything else)
    mkInstalledSystem = dir: withPlasma: finix.lib.finixSystem {
      inherit (pkgsTarget) lib;

      modules = [
        { nixpkgs.pkgs = lib.mkDefault pkgsTarget; }
        (dir + "/configuration.nix")
        (dir + "/sessions.nix")
        (dir + "/branding.nix")
      ]
      ++ lib.optional withPlasma (dir + "/plasma.nix")
      ++ (with finix.nixosModules; [
        nix-daemon
        chronyd
        bluetooth
        openssh
        sysklogd
        limine
        sudo
        polkit
        getty
        bash
        dhcpcd
        iwd
        regreet
        upower
        labwc
        sway
        niri
        lxqt
        mango
        pipewire
        wireplumber
        rtkit
        xwayland-satellite
        xorg
      ]);

      specialArgs = {
        modulesPath = toString nixpkgs + "/nixos/modules";
        inherit inputs;
      };
    };

    everythingSystem = mkInstalledSystem ./iso/everything-session true;
    everythingMdevdSystem = mkInstalledSystem ./iso/everything-mdevd-session false;

    sessionPackagesOf = cfg: [
      cfg.programs.labwc.package
      cfg.programs.sway.package
      cfg.programs.niri.package
      cfg.programs.mango.package
      cfg.programs.pipewire.package
      cfg.programs.wireplumber.package
      cfg.programs.xorg.package
      cfg.programs.xinit.package
      cfg.programs.xwayland-satellite.package
    ]
    ++ lib.filter (p: lib.elem (p.pname or "") [ "gluewc" "nvwm" "vxwm" ]) cfg.environment.systemPackages;

    prebuiltSessionPackages =
      sessionPackagesOf everythingMdevdSystem.config
      ++ sessionPackagesOf everythingSystem.config
      ++ [
        (pkgsTarget.callPackage (noctalia-src + "/nix/package.nix") { })
        newm-flake.packages.x86_64-linux.newm
        pkgsTarget.quickshell
        pkgsTarget.rofi
      ];
  in {
    nixosConfigurations.finix-iso = lib.nixosSystem {
      system = "x86_64-linux";
      specialArgs = {
        finixPrebuiltSessions = prebuiltSessionPackages;
      };
      modules = [
        "${nixpkgs}/nixos/modules/installer/cd-dvd/installation-cd-graphical-calamares-plasma6.nix"
        ./iso/finix-iso.nix
      ];
    };

    packages.x86_64-linux.prebuilt-sessions = pkgsTarget.linkFarm "finix-prebuilt-sessions" (
      lib.imap0 (i: p: {
        name = "${toString i}-${p.pname or p.name}";
        path = p;
      }) prebuiltSessionPackages
    );

    packages.x86_64-linux.everything-toplevel =
      everythingSystem.config.system.build.toplevel;
    packages.x86_64-linux.everything-mdevd-toplevel =
      everythingMdevdSystem.config.system.build.toplevel;

    packages.x86_64-linux.iso =
      self.nixosConfigurations.finix-iso.config.system.build.isoImage;
  };
}