Moonrise/build.gradle.kts at mc/26.1 · Tuinity/Moonrise · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
import me.modmuss50.mpp.ModPublishExtension
import me.modmuss50.mpp.ReleaseType

plugins {
    id("common-conventions")
    id("net.neoforged.moddev")
    id("me.modmuss50.mod-publish-plugin") version "1.1.0" apply false
    id("xyz.jpenilla.quiet-fabric-loom-companion")
}

val aw2at = Aw2AtTask.configureDefault(
    project,
    layout.projectDirectory.file("src/main/resources/moonrise.accesswidener").asFile,
    sourceSets.main.get()
)

sourceSets.create("lithium")

neoForge {
    neoFormVersion = libs.versions.neoform.get()
    validateAccessTransformers = true
    accessTransformers.files.setFrom(aw2at.flatMap { t -> t.outputFile })
    addModdingDependenciesTo(sourceSets.getByName("lithium"))
}

dependencies {
    compileOnly(libs.mixin)
    compileOnly(libs.mixinExtras)
    compileOnly(libs.asm)

    api(libs.concurrentutil) { isTransitive = false }
    api(libs.yamlconfig) { isTransitive = false }
    api(libs.snakeyaml)

    // todo: does cloth publish a platform-agnostic jar in mojang mappings?
    compileOnly(libs.clothConfig.neoforge)

    "lithiumCompileOnly"("maven.modrinth:lithium:${rootProject.property("neo_lithium_version")}")
    compileOnly(sourceSets.getByName("lithium").output)
}

subprojects {
    plugins.apply("me.modmuss50.mod-publish-plugin")

    configure<ModPublishExtension> {
        if (project.version.toString().contains("-beta.")) {
            type = ReleaseType.BETA
        } else {
            type = ReleaseType.STABLE
        }
        changelog = providers.environmentVariable("RELEASE_NOTES")

        val supportedMcVersions = rootProject.property("supported_minecraft_versions").toString().split(',')

        modrinth {
            projectId = "KOHu7RCS"
            accessToken = providers.environmentVariable("MODRINTH_TOKEN")
            minecraftVersions = supportedMcVersions
        }

        curseforge {
            projectId = "1096335"
            accessToken = providers.environmentVariable("CURSEFORGE_TOKEN")
            minecraftVersions = supportedMcVersions
        }
    }
}