notes.osl

def isValidTitle(string title) boolean (
    if title.strip() == "" (
        return false
    )
    
    for i title.len (
        string char = title[i].toStr()
        number ord = char.ord()
        if ord < 32 or ord > 126 (
            return false
        )
    )
    
    return true
)

def writeNote(string token, string title, string content) boolean (
    if !isValidTitle(title) (
        return false
    )
    
    auto client = getClient(token)

    string path = notesDir ++ "/" ++ title ++ ".txt"

    any err = null

    if client.Exists(path) (
        err = client.WriteFile(path, content)
    ) else (
        err = client.CreateFile(path, content)
    )

    client.Commit()

    return err == null
)

def listNotes(string token) array (
    auto client = getClient(token)

    array dir = client.ListDir(notesDir)

    array notes = []
    for i dir.len (
        if dir[i].toStr().endsWith(".txt") (
            notes.append(dir[i].toStr().trim(1, -5))
        )
    )

    return notes
)

def listNotesWithMetadata(string token) array (
    auto client = getClient(token)

    array dir = client.ListDir(notesDir)

    array notes = []
    for i dir.len (
        if dir[i].toStr().endsWith(".txt") (
            string title = dir[i].toStr().trim(1, -5)
            string path = notesDir ++ "/" ++ dir[i].toStr()
            
            auto file = client.ReadFile(path).toArray()
            if file[2] == null (
                number created = file[1][IdxCreated].toNum()
                number edited = file[1][IdxEdited].toNum()
                
                notes.append({
                    title: title,
                    created: created,
                    edited: edited
                })
            )
        )
    )

    return notes
)

def noteExists(string token, string title) boolean (
    if !isValidTitle(title) (
        return false
    )
    
    auto client = getClient(token)
    string path = notesDir ++ "/" ++ title ++ ".txt"
    return client.Exists(path)
)

def readNote(string token, string title) string (
    if !isValidTitle(title) (
        return ""
    )
    
    auto client = getClient(token)
    string path = notesDir ++ "/" ++ title ++ ".txt"

    auto file = client.ReadFileContent(path).toArray()
    if file[2] != null (
        return ""
    )
    return file[1].assert(string)
)

def deleteNote(string token, string title) boolean (
    if !isValidTitle(title) (
        return false
    )
    
    auto client = getClient(token)
    string path = notesDir ++ "/" ++ title ++ ".txt"
    any err = client.Remove(path)
    if err == null (
        client.Commit()
        return true
    )
    return false
)

def renameNote(string token, string oldTitle, string newTitle) boolean (
    if !isValidTitle(oldTitle) or !isValidTitle(newTitle) (
        return false
    )
    
    auto client = getClient(token)
    string path = notesDir ++ "/" ++ oldTitle ++ ".txt"
    string newPath = notesDir ++ "/" ++ newTitle ++ ".txt"
    any err = client.Rename(path, newPath)
    
    string tagsPath = notesDir ++ "/tags.json"
    if client.Exists(tagsPath) (
        object allTags = readAllTags(token)
        
        if allTags.contains(oldTitle) (
            allTags[newTitle] = allTags[oldTitle]
            allTags.delete(oldTitle)
            writeAllTags(token, allTags)
        )
    )
    
    if err == null (
        client.Commit()
        return true
    )
    return false
)

def writeAllTags(string token, object allTags) boolean (
    auto client = getClient(token)
    string path = notesDir ++ "/tags.json"
    
    string json = allTags.JsonStringify()
    
    any err = null
    if client.Exists(path) (
        err = client.WriteFile(path, json)
    ) else (
        err = client.CreateFile(path, json)
    )
    
    client.Commit()
    return err == null
)

def readAllTags(string token) object (
    auto client = getClient(token)
    string path = notesDir ++ "/tags.json"
    
    if !client.Exists(path) (
        return {}
    )
    
    auto file = client.ReadFileContent(path).toArray()
    if file[2] != null (
        return {}
    )
    
    string json = file[1].assert(string)
    any parsed = json.JsonParse()
    
    if typeof(parsed) == "array" (
        client.Remove(path)
        client.Commit()
        return {}
    )

    if typeof(parsed) != "object" (
        return {}
    )
    
    return parsed.assert(object)
)

def writeTags(string token, string title, array tags) boolean (
    object allTags = readAllTags(token)
    allTags[title] = tags
    return writeAllTags(token, allTags)
)

def readTags(string token, string title) array (
    object allTags = readAllTags(token)
    
    if allTags.contains(title) (
        return allTags[title].assert(array)
    )
    
    return []
)

def deleteTags(string token, string title) boolean (
    object allTags = readAllTags(token)
    
    if allTags.contains(title) (
        allTags.delete(title)
    )
    
    return writeAllTags(token, allTags)
)

def getAllTags(string token) array (
    object allTags = readAllTags(token)
    array uniqueTags = []
    object tagSet = {}
    
    array titles = allTags.getKeys()
    for i titles.len (
        string title = titles[i].toStr()
        array tags = allTags[title].assert(array)
        for j tags.len (
            string tag = tags[j].toStr()
            if !tagSet.contains(tag) (
                tagSet[tag] = true
                uniqueTags.append(tag)
            )
        )
    )
    
    return uniqueTags
)

def filterNotesByTags(string token, array filterTags) array (
    object allTags = readAllTags(token)
    array filteredNotes = []
    
    array notes = listNotes(token)
    for i notes.len (
        string title = notes[i].toStr()
        array noteTags = []
        
        if allTags.contains(title) (
            noteTags = allTags[title]
        )
        
        boolean matches = false
        for j filterTags.len (
            string filterTag = filterTags[j].toStr()
            for k noteTags.len (
                if noteTags[k].toStr() == filterTag (
                    matches = true
                    break
                )
            )
            if matches (
                break
            )
        )
        
        if matches (
            filteredNotes.append(title)
        )
    )
    
    return filteredNotes
)