simOpenMesh/CMakeLists.txt at master · CoppeliaRobotics/simOpenMesh · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
cmake_minimum_required(VERSION 3.16.3)
project(simOpenMesh)

set(CMAKE_INCLUDE_CURRENT_DIR ON)
set(CMAKE_MACOSX_RPATH 1)

find_package(Boost REQUIRED COMPONENTS serialization)

if(NOT COPPELIASIM_INCLUDE_DIR)
    if(DEFINED ENV{COPPELIASIM_ROOT_DIR})
        set(COPPELIASIM_INCLUDE_DIR $ENV{COPPELIASIM_ROOT_DIR}/programming/include)
    else()
        set(COPPELIASIM_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/../include)
    endif()
endif()
list(APPEND CMAKE_MODULE_PATH
    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules
    ${COPPELIASIM_INCLUDE_DIR}/cmake)
find_package(CoppeliaSim 4.5.1.7 REQUIRED COMPONENTS simLib-1 simLib-scriptFunctionData-1 simStack-1)
find_package(Eigen3 REQUIRED)

if(WIN32)
    find_package(OpenMesh CONFIG REQUIRED)
    set(OPENMESH_LIBRARIES OpenMeshCore OpenMeshTools)
else()
    include(ExternalProject)
    set(OPENMESH_VERSION 8.1)
    set(OPENMESH_PREFIX ${CMAKE_CURRENT_BINARY_DIR}/OpenMesh-${OPENMESH_VERSION}-prefix)
    set(OPENMESH_SRC_DIR ${OPENMESH_PREFIX}/src/OpenMesh-${OPENMESH_VERSION})
    set(OPENMESH_BUILD_DIR ${OPENMESH_PREFIX}/src/OpenMesh-${OPENMESH_VERSION}-build)
    ExternalProject_Add(OpenMesh-${OPENMESH_VERSION}
        URL https://www.graphics.rwth-aachen.de/media/openmesh_static/Releases/${OPENMESH_VERSION}/OpenMesh-${OPENMESH_VERSION}.tar.gz
        CMAKE_ARGS -DCMAKE_POLICY_VERSION_MINIMUM=3.5 -DCMAKE_C_FLAGS=-fPIC -DCMAKE_CXX_FLAGS=-fPIC -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE} -DCMAKE_TOOLCHAIN_FILE=${CMAKE_TOOLCHAIN_FILE} -DBUILD_APPS=OFF
        BUILD_COMMAND ${CMAKE_COMMAND} --build ${OPENMESH_BUILD_DIR} --config ${CMAKE_BUILD_TYPE}
        INSTALL_COMMAND ""
    )
    set(OPENMESH_INCLUDE_DIRS ${OPENMESH_SRC_DIR}/src)
    string(TOLOWER ${CMAKE_BUILD_TYPE} CMAKE_BUILD_TYPE_L)
    if(CMAKE_BUILD_TYPE_L MATCHES debug)
        set(OPENMESH_DEBUG_SUFFIX d)
    endif()
    set(OPENMESH_LIBRARIES
        ${OPENMESH_BUILD_DIR}/Build/lib/${CMAKE_SHARED_LIBRARY_PREFIX}OpenMeshCore${OPENMESH_DEBUG_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX}
        ${OPENMESH_BUILD_DIR}/Build/lib/${CMAKE_SHARED_LIBRARY_PREFIX}OpenMeshTools${OPENMESH_DEBUG_SUFFIX}${CMAKE_STATIC_LIBRARY_SUFFIX})
endif()

include_directories(${CMAKE_CURRENT_BINARY_DIR}/generated)
include_directories(${CMAKE_CURRENT_SOURCE_DIR}/external)
include_directories(${OPENMESH_INCLUDE_DIRS})

coppeliasim_add_plugin(
    simOpenMesh
    LEGACY
    SOURCES
    sourceCode/simOpenMesh.cpp
)
target_compile_definitions(simOpenMesh PRIVATE SIM_MATH_DOUBLE)
if(NOT WIN32)
    add_dependencies(simOpenMesh OpenMesh-${OPENMESH_VERSION})
endif()
target_link_libraries(simOpenMesh PRIVATE ${OPENMESH_LIBRARIES})
coppeliasim_add_lua(lua/simOpenMesh.lua)
coppeliasim_add_lua(lua/simOpenMesh-ce.lua)
coppeliasim_add_addon("addOns/Mesh decimation.lua")